Saving a Movie of an Animated Pendulum

ClearAll["Global`*"];

g=9.8;(* gravitational acceleration in m/(s^2)*)
len=1; (* length of pendulum arm, in meters*)
rb=0.05; (* radius of ball, as fraction of length*)
period=2 π (Sqrt[(len/g)]); (* period in seconds *)
amplitude = 0.5 ;(*amplitude is in radians *)
timestep= (period/100); (* This is the duration of each frame of motion, so this movie will have 100 frames *)
ϕ[t_]:=amplitude Cos[((2 π t)/period)];

(* warning! this notebook doesn't even bother to show the user what is being made! *)
(* you should always use "animate" or "manipulate" to first make sure it's what you want! *)
plotbob[t_]:=Graphics[{{Thin,Blue,Line[{{0,len},{len Sin[ϕ[t]],len (1-Cos[ϕ[t]])}}]},{PointSize[rb/len],Red,Point[{len Sin[ϕ[t]],len (1-Cos[ϕ[t]])}]}},Frame->False, PlotRange ->{{-len ,len},{-.25len,1.25len}}];

myframes=Table[plotbob[t],{t,0,period,timestep}]; (* make a movie of ONE period of motion *)
path = "C:\\Users\\pogo\\Desktop\\MMA\\pendulum.gif";
(* You'll obviously need to put in a path that's appropriate to your own computer!! *)
Export[path,myframes,"DisplayDurations"->0.033,"AnimationRepetitions"->∞]; 
(* options are gif, swf, avi, mov *)
(* gif looks very nice, but might not "run" in a mere image viewer. It is easily embedded into PowerPoint, etc. *)
(* avi is large and ugly. *)
(* swf is intended for insertion into a web page *)
(* mov requires Mathematica to be able to talk to Apple's "Quicktime" during the run *)
(* "DisplayDurations" specifies the amount of time, in seconds, that each frame of the animation will be displayed. So, if DisplayDurations is 2 seconds, and you have 30 frames, then the resulting gif file will run for one minute. A "typical" frame duration is 0.03333 seconds, resulting in a 30 frames per second animation. *)
(* But, suppose you already have 100 frames, and you want your video to last 5 seconds, then you'd require 20 fps, or a single frame duration of 0.05 instead of 0.333 s. *)